` Demonstrates a server that receives sound data from clients
` and relays it to other clients



iResult as integer

RecvPacket = mn Create Packet()

` Start server
print "Starting server..."
mn Start 1,0

mn Set Local 0,"",2525,"",2525
mn Set Buffer Sizes 0,15000,1024,1
mn Start Server 0,50,0,4
print "Server started"
print "Local TCP IP: " + mn Get Local IP TCP(0)
print "Local TCP port: " + str$(mn Get Local Port TCP(0))
print "Local UDP IP: " + mn Get Local IP UDP(0)
print "Local UDP port: " + str$(mn Get Local Port UDP(0))
print

` Main loop
do
	` Accept new connections
	iResult = mn Client Joined(0)
	if iResult > 0
		print "New client joined: " + str$(iResult)
		print "Client TCP IP: " + mn Get Client IP TCP(0,iResult)
		print "Client TCP port: " + str$(mn Get Client Port TCP(0,iResult))
		print "Client UDP IP: " + mn Get Client IP UDP(0,iResult)
		print "Client UDP port: " + str$(mn Get Client Port UDP(0,iResult))
	endif

	` Leaving clients
	iResult = mn Client Left(0)
	if iResult > 0
		print "Client left: " + str$(iResult)
	endif

	` New TCP packets
	for cl = 1 to mn Get Max Clients(0)
		iResult = mn Recv UDP(0,RecvPacket,cl,0)
		
		if iResult > 0
			` Add client ID to start of packet
			mn Set Cursor RecvPacket,0
			mn Insert RecvPacket,4
			mn Add Int RecvPacket,cl

			` Send packet to clients
			mn Send UDP All 0,RecvPacket,0,1,cl
		endif
	next cl
loop