` Create packet
Packet = mn Create Packet()
mn Set Memory Size Packet, 1024

` Create key to be used when encrypting
` The 4 parameters of mnCreateKey256 act as a password
` Without these values it is impossible to decrypt the packet
Key = mn Create Key 256(1251521,15215215,121512515,151252151)

` Get input
InputData$ as string
Input "Enter data to be encrypted: ",InputData$
print
print


` Load input into packet
mn Add String Packet,InputData$,0,0

` Display packet contents
DisplayContents(Packet,"Original contents: ")

` Encrypt the packet using the key that we created earlier
mn Encrypt Packet,Key

` Display encrypted contents
DisplayContents(Packet,"Encrypted contents: ")

` Decrypt packet using the key that we created earlier
mn Decrypt Packet,Key

` Display decrypted contents
DisplayContents(Packet,"Decrypted contents: ")

print "Press any key to exit..."
wait key
end


` Outputs the contents of Packet with TextData$ prefix
function DisplayContents(Packet as double integer, TextData$ as string)
   ` Move cursor to start of packet
   mn Set Cursor Packet, 0

   ` Return string containing contents of packet
   Contents$ = mn Get String(Packet, mn Get Used Size(Packet), 1)

   ` Write packet contents to screen
   print TextData$
   print Contents$
   print
endfunction